MS WINDOWS - Prebacivanje štampe u velikom mrežnom okruženju

CILJ :
Prebacivanje štampe na slobodni štampač zbog kvara postojećeg štampača.

DODATNI IZAZOV :
1. Problem otkaza mrežnog štampača kojeg koristi veliki broj korisnika, 
2. Problem sa podešavanjem štampe u dos programima (clipper/dbase aplikacije),
3. Nepostojanje stručne osobe koja brzo može rešiti problem.

TRAŽENA FUNKCIONALNOST:
1. Rešenje problema ukoliko je moguće "jednim klikom" od strane korisnika koji je onemogućen da štampa.
2. Premošćivanje problema što pre kako bi se smanjio dodatni stres, i pritisak na obične korisnike koji su obično već pod velikim opterećenjem,
3. Posle servisiranja pokvarenog štampača, vraćanje na uobičajeno podešavanje "jednim klikom",
4. Automatizacija kroz Active Directory.


TESTOVI :
Testovi su uspešno izvršeni sa štampačima HP serije 4100, 4050,1300,5P/6P,1150,1100,1300,1010/1018/1020


BENEFITI IMPLEMENTACIJE :
1. Fleksibilnost - krajnji korisnik prebacuje štampu na bilo koji štampač iz grupe definisanih štampača,
2. Prebacivanje rešenja problema na stranu krajnjeg korisnika, bez dodatne intervencije it stručnjaka.
3. Potpuna automatizacija korišćenjem Active Directory-ja


KORIŠĆENI DODATNI ALATI:
1. Defprint alat (http://www.aylott.com.au/software.htm)
2. Dodatni skriptovi.

I DEO

_________________

1. Instalirati program defprint na svim računarima koji su kritični u smislu štampe: iskopirati defprint.exe u ~\System32 folder,
2. Identifikovati štampače koji su deljeni na mreži (Share-ovane štampače), kroz imena share-ova.
3. Identifikovati grupe korisnika koji koriste postojeće štampače.
4. Identifikovati postojanje eventualnog problema kod štampe u "legacy" aplikacijama (dos/clipper-dbase)
   
   
   1. Razrešiti potencijalni LPT1/LPT2 problem koji se ogleda u tome da ako računar koji štampa u legacy aplikacijama NIJE print server, a ako je zauzet LPT1 port, onda se ostvaruje preduslov da se izvrši komanda : DEVCON DISABLE *PNP04* ,naravno, pod administratorskim kredencijalom.
   2. Ukoliko na ovom računaru i dalje nije moguće da običan korisnik računara (domain user) i dalje nije u mogućnosti da preusmeri štampu putem komande :
      NET USE LPT1/2 onda se posle akcije iz 4.1. posmatrani računar mora restartovati.
   3. Ukoliko smo na računaru koji nije print server usmerili LPT1 port za štampu, onda se iz shell-a mora pokrenuti program EDIT (sa admin pristupom) :
      
      
      1. Pokrenuti EDIT,
      2. Ići u Options, Settings,
      3. Izabrati LPT1, ili LPT2 u zavisnosti od podešavanja u tački 4.2.
      
      
      

II DEO
____________

1. ORGANIZOVANJE I STRUKTURA ŠTAMPAČA I NJIHOVIH SHARE-ova
      1. Definicija štampača se obavlja kreiranjem batch fajla : Definicije.Print.Servera.bat
      2. Primer :
   
   @echo off
   
   set dc=KOMERC
   set dcshare=HP4100
   
   set dc2=TRINITY
   set dc2share=HP4100T
   
   set sb=SERVISBAR
   set sbshare=HP6P
   
   set m01=MAGACIN01
   set m01share=HPLASERJ
   
   set gar=GARANCIJE
   set garshare=HP1150
   
   set rd=REZDEL
   set rdshare=HP1300Ljubo
   
   set kd=KNJIGDELL
   set kdshare=HP1150G
   
   set bl=BLAGAJNA
   set blshare=OLIVETTI
   
   set rce2=RC2
   set rce2share=HP5550
   
      3. Definicija poziva štampača se obavlja kreiranjem batch fajla :Print.Server.Pozivi.bat
      4. PRIMER :
   
   REM #####################################################
   REM #                            #
   REM #   Ukoliko racunar koji ciji se stampac pokvari    #
   REM #  ili ima potrebu da se prikljuci na neki rezervni    #
   REM #    print share, onda taj racunar moze rezervisati    #
   REM #  SAMO LPT2 PORT !!! Izuzetak je racunar BLAGAJNE    #
   REM #                            #
   REM #####################################################
   
   REM #####################################################
   REM #                            #
   REM #   Upisi u logove koriscenje preusmeravanja    #
   REM #              stampe                #
   REM #                            #
   REM #####################################################
   
   @echo off
   
   echo ______________________________________________________________ >> "G:\Logovi\preusmerenje.txt"
   echo >> "G:\Logovi\preusmerenje.txt"
   echo Datum Preusmerenja: [%date%] >> "G:\Logovi\preusmerenje.txt"
   echo Vreme Preusmerenja: [%time%] >> "G:\Logovi\preusmerenje.txt"
   echo Racunar sa koga se Preusmerava: [%computername%] >> "G:\Logovi\preusmerenje.txt"
   echo Osoba koja Preusmerava: [%username%] >> "G:\Logovi\preusmerenje.txt"
   echo Stampac na koji se preusmerava stampa: [%printServer%] >> "G:\Logovi\preusmerenje.txt"
   echo Print Share na koji se preusmerava : [%printServerShare%] >> "G:\Logovi\preusmerenje.txt"
   
   echo Korisnik vraca na staro : [%PovratakNaStaro%] >> "G:\Logovi\preusmerenje.txt"
   
   
   echo >> "G:\Logovi\preusmerenje.txt"
   echo ______________________________________________________________ >> "G:\Logovi\preusmerenje.txt"
   
   
   if %computername%==%bl% goto PrintServerBLAGAJNA_
   if %computername%==%printServer% goto Poruka
   if %computername%==%sb% goto PrintServeri_
   if %computername%==%m01% goto PrintServeri_
   if %computername%==%gar% goto PrintServeri_
   if %computername%==%rd% goto PrintServeri_
   
   goto Preskoci_
   
   :PrintServerBLAGAJNA_
   defprint /D %blshare%
   
   
   :Preskoci_
   
   net use LPT1 \\%printServer%\%printServerShare%
   Call L:\PRINTBAR.lpt1.BAT
   goto Poruka
   
   
   :PrintServeri_
   net use LPT2 \\%printServer%\%printServerShare%
   Call L:\PRINTBAR.lpt2.BAT
   
   
   set poruka1="U Plavim programima OBAVEZNO koristite podesavanje STAMPA-2"
   net send %computername% %poruka1%
   
   :Poruka
   
   set poruka2="Stampanje preusmereno na stampac: "
   net send %computername% %poruka2% %printServerShare%
   
   :Kraj
   Exit
   
      5. Definicija poziva konkretnog štampača se obavlja kreiranjem batch fajla : npr. prebaci.na.BLAGAJNU.bat
      6. PRIMER :     
   REM #####################################################
   REM #                            #
   REM #    Definicije Print Servera            #
   REM #                            #
   REM #####################################################
   
   @echo off
   
   set printServer=BLAGAJNA
   set printServerShare=OLIVETTI
   
   REM #############################################################
   REM #                                #
   REM #       Definicije ostalih Print Servera, u mrezi        #
   REM #                                #
   REM #############################################################
   
   G:
   call G:\SYS.SCRIPTS\startup.scripts\Sektori\Zajednicki\Stampaci\Skripts\Definicije.Print.Servera.bat
   
   
   REM #####################################################
   REM #                            #
   REM #  Pocetak Izvrsavanja zamena default-nih stampaca    #
   REM #                            #
   REM #####################################################
   
   defprint /D %printServerShare%
   
   net use lpt1 /delete
   net use lpt2 /delete
   
   
   REM #####################################################
   REM #                            #
   REM #   Proveri koji racunar poziva promenu stampaca    #
   REM #                            #
   REM #####################################################
   
   call G:\SYS.SCRIPTS\startup.scripts\Sektori\Zajednicki\Stampaci\Skripts\Print.Server.Pozivi.bat
   
   7. Definicija poziva skripta za vraćanje na stanje pre kvara štampača : Vrati.Na.Staro.bat  
   6. PRIMER :     
2. 
   REM #############################################################
   REM #                                #
   REM #   Vracanje na default-ni stampac pre izmene ili kvara    #
   REM #                                #
   REM #############################################################
   
   @echo off
   
   REM #############################################################
   REM #                                #
   REM #     Ulazak i lokaciju sa definicijama skriptova        #
   REM #                                #
   REM #############################################################
   
   G:
   cd "G:\SYS.SCRIPTS\startup.scripts\Sektori\Zajednicki\Stampaci"
   set comp=%computername%
   set PovratakNaStaro=true
   
   
   REM #############################################################
   REM #                                #
   REM #       Definicije Print Servera, i njihovih share-ova    #
   REM #                                #
   REM #############################################################
   
   call G:\SYS.SCRIPTS\startup.scripts\Sektori\Zajednicki\Stampaci\Skripts\Definicije.Print.Servera.bat
   
   
   REM #############################################################
   REM #                                #
   REM #         Za sve racunare koji koriste KOMERC        #
   REM #       kao print server, treba vratiti na HP4100 share    #
   REM #                                #
   REM #############################################################
   
   REM #############################################################
   REM #                                #
   REM #              Print server ne zauzima LPT            #
   REM #                                #
   REM #############################################################
   
   if %comp% == %dc% goto kraj
   
   REM #############################################################
   REM #                                #
   REM #       Definicije Print Klijenta koji koriste         #
   REM #            print server KOMERC                #
   REM #                                #
   REM #############################################################
   
   if %comp% == PRIJEM1 goto dc_
   if %comp% == PRIJEM2 goto dc_
   if %comp% == PRIJEM3 goto dc_
   
   if %comp% == JELENATASIC goto dc_
   
   if %comp% == BLAGAJNA goto dc_
   if %comp% == BLAGAJNA2 goto dc_
   
   if %comp% == REZ1 goto dc_
   if %comp% == MILJANPULT goto dc_
   
   
   REM #############################################################
   REM #                                #
   REM #           Za sve racunare koji koriste SERVISBAR        #
   REM #    kao print server, treba vratiti na HP6P share        #
   REM #                                #
   REM #############################################################
   
   REM #############################################################
   REM #                                #
   REM #       Definicije Print Klijenta koji koriste         #
   REM #            print server SERVISBAR                #
   REM #                                #
   REM #############################################################
   
   if %comp% == %sb% goto sb_
   
   if %comp% == ELSAUTOK goto sb_
   if %comp% == MAJSTORI goto sb_
   
   
   REM #############################################################
   REM #                                #
   REM #           Za sve racunare koji koriste MAGACIN01        #
   REM #    kao print server, treba vratiti na HPLASERJ share    #
   REM #                                #
   REM #############################################################
   
   REM #############################################################
   REM #                                #
   REM #       Definicije Print Klijenta koji koriste         #
   REM #            print server MAGACIN01                #
   REM #                                #
   REM #############################################################
   
   if %comp% == %m01% goto m01_
   
   if %comp% == MAGACIN02 goto m01_
   if %comp% == MAGACIN03 goto m01_
   if %comp% == MAGACIN04 goto m01_
   
   
   REM #############################################################
   REM #                                #
   REM #           Za sve racunare koji koriste GARANCIJE        #
   REM #    kao print server, treba vratiti na HP1150 share        #
   REM #                                #
   REM #############################################################
   
   REM #############################################################
   REM #                                #
   REM #       Definicije Print Klijenta koji koriste         #
   REM #            print server GARANCIJE                #
   REM #                                #
   REM #############################################################
   
   if %comp% == %gar% goto gar_
   
   if %comp% == PEVAC goto gar_
   if %comp% == BARLIMAR goto gar_
   
   
   REM #############################################################
   REM #                                #
   REM #           Za sve racunare koji koriste stampac u        #
   REM #           RACUNOVODSTVU kao print server            #       
   REM #        treba vratiti na HP1150G  share            #
   REM #                                #
   REM #############################################################
   
   REM #############################################################
   REM #                                #
   REM #       Definicije Print Klijenta koji koriste         #
   REM #            print server GARANCIJE                #
   REM #                                #
   REM #############################################################
   
   if %comp% == %kd% goto kd_
   
   if %comp% == FINANSIJE2 goto kd_
   if %comp% == BUBA goto kd_
   if %comp% == GOCAKNJIG goto kd_
   
   
   REM #############################################################
   REM #                                #
   REM #           Za sve racunare koji koriste stampac        #
   REM #          BLAGAJNE kao print server treba vratiti         #       
   REM #           na OLIVETTI share                #
   REM #                                #
   REM #############################################################
   
   REM #############################################################
   REM #                                #
   REM #       Definicije Print Klijenta koji koriste         #
   REM #            print server BLAGAJNA                #
   REM #                                #
   REM #############################################################
   
   if %comp% == %bl% goto bl_
   
   REM #############################################################
   REM #                                #
   REM #           Za sve racunare koji koriste REZDEL        #
   REM #    kao print server, treba vratiti na HP1300ljubo share    #
   REM #                                #
   REM #############################################################
   
   REM #############################################################
   REM #                                #
   REM #       Definicije Print Klijenta koji koriste         #
   REM #            print server REZDEL                #
   REM #                                #
   REM #############################################################
   
   if %comp% == %rd% goto rd_
   
   
   REM #############################################################
   REM #                                #
   REM #           Za sve racunare koji koriste RC2            #
   REM #    kao print server, treba vratiti na HP5550 share        #
   REM #                                #
   REM #############################################################
   
   REM #############################################################
   REM #                                #
   REM #       Definicije Print Klijenta koji koriste         #
   REM #            print server REZDEL                #
   REM #                                #
   REM #############################################################
   
   if %comp% == %rce2% goto rce2_
   if %comp% == RCDELL goto rce2_
   
   goto kraj
   
   REM #############################################################
   REM #############################################################
   REM #############################################################
   
   
   :dc_
   
   prebaci.na.PRIJEM.HP.4100.lnk
   
   goto kraj
   
   REM #############################################################
   
   
   :sb_
   
   prebaci.na.SERVISNI.Racunar.lnk
   
   goto kraj
   
   REM #############################################################
   
   
   :m01_
   
   prebaci.u.MAGACIN.lnk
   
   goto kraj
   
   REM #############################################################
   
   
   :gar_
   
   prebaci.u.GARANCIJE.lnk
   
   goto kraj
   
   REM #############################################################
   
   
   :rd_
   prebaci.kod.NJEGOVANOVICA.lnk
   
   goto kraj
   
   REM #############################################################
   
   
   :kd_
   prebaci.u.RACUNOVODSTVO.lnk
   
   goto kraj
   
   REM #############################################################
   
   :rce2_
   IT.Kolor.stampac.lnk
   
   goto kraj
   
   REM #############################################################
   
   
   :bl_
   BLAGAJNA.Matricni.lnk
   
   REM #############################################################
   
   :kraj
   
   
   NAPOMENE: